You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

UGameEngine.pro 2.9KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115
  1. #-------------------------------------------------
  2. #
  3. # Project created by QtCreator 2016-08-31T16:32:08
  4. #
  5. #-------------------------------------------------
  6. QT += gui core
  7. TARGET = UGameEngine
  8. TEMPLATE = lib
  9. CONFIG += c++11
  10. DEFINES += UGAMEENGINE_LIBRARY
  11. SOURCES += engine/ugameengine.cpp \
  12. engine/abstractrenderdevice.cpp \
  13. entities/ugeentity.cpp \
  14. utils/colorvector3d.cpp \
  15. entities/ugeentitycube.cpp \
  16. entities/ugeentityaxes.cpp \
  17. utils/wavefrontobj.cpp \
  18. entities/ugeentitywavefrontobj.cpp \
  19. utils/texturevector3d.cpp \
  20. utils/vector2d.cpp \
  21. utils/vector3d.cpp \
  22. utils/matrix3x3.cpp \
  23. utils/tools.cpp \
  24. cameras/abstractcamera.cpp \
  25. cameras/rotationcamera.cpp \
  26. cameras/freeflycamera.cpp
  27. HEADERS += engine/ugameengine.h\
  28. engine/abstractrenderdevice.h \
  29. entities/ugeentity.h \
  30. utils/vector3d.h \
  31. utils/colorvector3d.h \
  32. entities/ugeentitycube.h \
  33. entities/ugeentityaxes.h \
  34. utils/wavefrontobj.h \
  35. entities/ugeentitywavefrontobj.h \
  36. utils/texturevector3d.h \
  37. utils/vectorxd.h \
  38. utils/vectorxd.hxx \
  39. utils/vector2d.h \
  40. utils/matrixmxn.h \
  41. utils/matrixmxn.hxx \
  42. utils/matrix3x3.h \
  43. utils/tools.h \
  44. utils/tools.hxx \
  45. cameras/abstractcamera.h \
  46. cameras/rotationcamera.h \
  47. cameras/freeflycamera.h \
  48. utils/matrixdebug.h \
  49. utils/matrixdebug.hxx
  50. # FLEX && BISON
  51. LIBS += -lfl -ly
  52. FLEXSOURCES = utils/lexer-wavefront-obj.l \
  53. utils/lexer-wavefront-mtl.l
  54. BISONSOURCES = utils/parser-wavefront-obj.y \
  55. utils/parser-wavefront-mtl.y
  56. OTHER_FILES += \
  57. $$FLEXSOURCES \
  58. $$BISONSOURCES
  59. flexsource.input = FLEXSOURCES
  60. flexsource.output = ${QMAKE_FILE_BASE}.cpp
  61. flexsource.commands = flex --header-file=${QMAKE_FILE_BASE}.h -o ${QMAKE_FILE_BASE}.cpp ${QMAKE_FILE_IN}
  62. flexsource.variable_out = SOURCES
  63. flexsource.name = Flex Sources ${QMAKE_FILE_IN}
  64. flexsource.CONFIG += target_predeps
  65. QMAKE_EXTRA_COMPILERS += flexsource
  66. flexheader.input = FLEXSOURCES
  67. flexheader.output = ${QMAKE_FILE_BASE}.h
  68. flexheader.commands = @true
  69. flexheader.variable_out = HEADERS
  70. flexheader.name = Flex Headers ${QMAKE_FILE_IN}
  71. flexheader.CONFIG += target_predeps no_link
  72. QMAKE_EXTRA_COMPILERS += flexheader
  73. bisonsource.input = BISONSOURCES
  74. bisonsource.output = ${QMAKE_FILE_BASE}.cpp
  75. bisonsource.commands = bison -d --defines=${QMAKE_FILE_BASE}.h -o ${QMAKE_FILE_BASE}.cpp ${QMAKE_FILE_IN}
  76. bisonsource.variable_out = SOURCES
  77. bisonsource.name = Bison Sources ${QMAKE_FILE_IN}
  78. bisonsource.CONFIG += target_predeps
  79. QMAKE_EXTRA_COMPILERS += bisonsource
  80. bisonheader.input = BISONSOURCES
  81. bisonheader.output = ${QMAKE_FILE_BASE}.h
  82. bisonheader.commands = @true
  83. bisonheader.variable_out = HEADERS
  84. bisonheader.name = Bison Headers ${QMAKE_FILE_IN}
  85. bisonheader.CONFIG += target_predeps no_link
  86. QMAKE_EXTRA_COMPILERS += bisonheader
  87. unix {
  88. target.path = /usr/lib
  89. INSTALLS += target
  90. }